; QE.LSP : 편집과 로딩(loading)을 한번에 처리하는 프로그램
; 작성일 : 1994. 1. 6.
; 작성자 : 최문선

; 전역변수
; *LAST* : 마지막으로 편집한 화일의 이름
(setq *LAST* (getvar "DWGNAME"))

; 문자열 중의 일부 문자를 찾은 후
; 그 문자를 중심으로 문자열을 분리한다

(defun divstr (str tok / strl tokl no cont)
    (setq strl (strlen str) tokl (strlen tok) no 1 cont T)
    (while (and (<= no strl) cont)
        (if (= (substr str no tokl) tok)
            (setq cont nil)
            (setq no (1+ no))
        )
    )
    (list (substr str 1 (1- no)) (substr str no))
)

(defun C:QE ( / ext sn rs)
    (setq ext (list ".LSP" ".MNU" ".SCR"))
    (setq sn (strcase (getstring (strcat "\nSource name <" *LAST* ">: "))))
    (if (= sn "") (setq sn *LAST*) (setq *LAST* sn))
    (setq rs (divstr sn "."))
    (if (= (cadr rs) "")
        (progn
            (while (and ext (not (findfile (strcat sn (car ext)))))
                (setq ext (cdr ext))
            )
            (if ext (setq sn (strcat sn (car ext))))
        )
    )
    (if (findfile sn) (setq sn (findfile sn)))
    (command "EDIT" sn)
    (setq rs (divstr sn "."))
    (if (findfile sn)
        (cond ((= (cadr rs) ".LSP") (load (car rs)))
              ((= (cadr rs) ".MNU") (command "MENU" (car rs)))
              ((= (cadr rs) ".SCR") (command "SCRIPT" (car rs)))
        )
    )
    (princ)
)