; MLINE.LSP : 다중선 그리는 프로그램
; 작성일    : 1994. 2. 1.
; 작성자    : 최문선

; 전역 변수
; *COPY* : 그려질 선의 개수
(setq *COPY* 2)

; *OFF* : 그려질 선들간의 간격
(setq *OFF* 1.0)

; 전역 변수 *COPY*의 값을 변경한다.

(defun C:SETCOPY ( / cpy)
    (setq cpy (getint (strcat "\nNew COPY value <" (itoa *COPY*) ">: ")))
    (if cpy (setq *COPY* cpy))
    (princ)
)

; 전역 변수 *OFF*의 값을 변경한다.

(defun C:SETOFF ( / off)
    (setq off (getdist (strcat "\nNew OFFSET value <" (rtos *OFF*) ">: ")))
    (if off (setq *OFF* off))
    (princ)
)

; 지정한 두점을 지나는 선을 
; OFF 거리만큼 옵셋한 선을 그린다.

(defun draw-oline (sp ep off / ang)
    (setq ang (+ (angle sp ep) (/ PI 2.0)))
    (command "LINE" (polar sp ang off)
                    (polar ep ang off) ""
    )
)

; 지정한 두점을 지나는 선을 지정한 
; 간격으로 지정한 회수만큼 그린다.

(defun draw-mline (sp ep num off)
    (if (<= 2 num)
        (progn
            (draw-oline sp ep off)
            (draw-oline sp ep (- off))
            (draw-mline sp ep (- num 2) (+ off *OFF*))
        )
    )
)

; 시작점과 끝점을 입력받는다.
; 지정한 개수가 홀수이면 중간선을 그린다.

(defun C:MLINE ( / sp ep)
    (initget 1)
    (setq sp (getpoint "\nFrom point: "))
    (initget 1)
    (setq ep (getpoint sp "\nTo point: "))
    (draw-mline sp ep *COPY* *OFF*)
    (if (/= (rem *COPY* 2) 0) (command "LINE" sp ep ""))
    (princ)
)