; DGRID.LSP : BOX를 가로, 세로로 지정한 회수만큼 등분하는 선을 그려주는 프로그램
; 작성일    : 1994. 2. 11.
; 작성자    : 최문선

; HATCH 명령을 사용하여 등분선을 그려주는 함수

(defun draw-grid (sp ep dx dy  / dp el ob)
    (command "PLINE" sp (list (car ep) (cadr sp))
                     ep (list (car sp) (cadr ep)) "CLOSE"
    )
    (setq dp (mapcar '- ep sp)
          dp (mapcar '/ dp (list dx dy))
    )
    (setq el (entlast))
    (setq ob (getvar "SNAPBASE"))
    (setvar "SNAPBASE" (list (car sp) (cadr sp)))
    (command "HATCH" "U" "90" (car dp) "N" el "")
    (command "HATCH" "U" "0" (cadr dp) "N" el "")
    (setvar "SNAPBASE" ob)
)

; BOX의 두 모서리와 가로, 세로방향 등분회수를 입력받는다.

(defun C:DGRID ( / sp ep oy dy dx)
    (graphscr)
    (initget (+ 1 2 4))
    (setq sp (getpoint "\nFirst corner: "))
    (initget (+ 1 2 4))
    (setq ep (getcorner sp "\nOther corner: "))
    (setq oy 2)
    (initget (+ 2 4))
    (setq dy (getint (strcat "\nNumber of rows(---) <" (itoa oy) ">: ")))
    (if (not dy) (setq dy oy))
    (initget (+ 2 4))
    (setq dx (getint (strcat "\nNumber of columns (|||) <" (itoa dy) ">: ")))
    (if (not dx) (setq dx dy))
    (draw-grid sp ep dx dy)
    (princ)
)