; DELTABLE.LSP : 지정한 TABLE을 제거하는 프로그램
; 작성일       : 1994. 9. 11.
; 작성자       : 최문선

; 전역변수
; #MODEL      : 시스템 변수값을 임시로 저장할 리스트
; #LBDATA     : LIST BOX에 들어있는 SYMBOL 들의 이름 리스트
; #SYMBOLNAME : 선택된 SYMBOL 이름
; #TABLETYPE  : 테이블형태
; #TABLELIST  : 테이블리스트

(setq #MODEL nil)
(setq #LBDATA nil)
(setq #SYMBOLNAME "")
(setq #TABLETYPE 2)
(setq #TABLELIST '(("BLOCK"    "Block"    "block_but" erase-entity)
                   ("DIMSTYLE" "Dimstyle" "dim_but"   erase-entity)
                   ("LAYER"    "Layer"    "layer_but" erase-entity)
                   ("LTYPE"    "Linetype" "ltype_but" erase-entity)
                   ("STYLE"    "Style"    "style_but" erase-entity)
                   ("UCS"      "UCS"      "ucs_but"   erase-define)
                   ("VIEW"     "View"     "view_but"  erase-define)
                   ("VPORT"    "Viewport" "vport_but" erase-define)))

; 사용할 시스템 변수의 현재값을 대피시킨다.
; 해당 시스템 변수의 값을 설정한다.

(defun push-mode ()
    (setq #MODEL (list (getvar "BLIPMODE")
                       (getvar "CMDECHO")
                       (getvar "EXPERT")
                       (getvar "OSMODE")
                 )
    )
    (setvar "BLIPMODE" 0)
    (setvar "CMDECHO" 0)
    (setvar "EXPERT" 1)
    (setvar "OSMODE" 0)
)

; 대피시켜둔 시스템 변수의 값을 복구시킨다.

(defun pop-mode ()
    (setvar "BLIPMODE" (car #MODEL))
    (setvar "CMDECHO" (cadr #MODEL))
    (setvar "EXPERT" (caddr #MODEL))
    (setvar "OSMODE" (cadddr #MODEL))
    (princ)
)

; 사용자 정의 에러 처리 함수
; 시스템 변수의 값을 복구시킨다.

(defun *ERROR* (msg)
    (if (/= msg "Function cancelled")
        (if (= msg "quit / exit abort")
            (princ)
            (princ (strcat "\nError: " msg "\n"))
        )
        (princ)
    )
    (redraw)
    (pop-mode)
)

; 패턴(pat 변수)과 일치하는 SYMBOL 명들로 LIST BOX를 구성한다.
; SYMBOL 명을 #LBDATA 변수에 담는다.

(defun symbol-list (key tname pat / tl in ln)
    (start_list key)
    (setq #LBDATA nil)
    (setq tl (tblnext tname T) in 0)
    (while tl
        (setq ln (cdr (assoc 2 tl)))
        (if (wcmatch ln pat)
            (progn
                (add_list ln)
                (setq #LBDATA (append #LBDATA (list ln)))
                (setq in (1+ in))
            )
        )
        (setq tl (tblnext tname))
    )
    (end_list)
)

; 패턴이 변경되었을 때 수행되는 CALL BACK 함수
; 패턴에 따라 LIST BOX의 내용을 재구성한다.

(defun do-pattern ( / pat)
    (setq pat (strcase (get_tile "pat_edit")))
    (symbol-list "pat_list" (car (nth #TABLETYPE #TABLELIST)) pat)
)

; LIST BOX 내의 항목이 선택되었을 때 수행되는 CALL BACK 함수
; SELECTION EDIT BOX의 내용을 선택된 SYMBOL 명으로 바꾼다.

(defun do-patlist ( / in)
    (setq in (get_tile "pat_list"))
    (setq in (nth (atoi in) #LBDATA))
    (set_tile "error" "")
    (set_tile "sel_edit" in)
)

; ERROR가 발생했을 때 수행되는 함수 (CALL BACK 함수 아님)
; 미리 설정된 ERROR TILE에 에러 내용을 표시한다.

(defun do-error (type)
    (set_tile "error" (strcat "Invalid " type " name."))
    (mode_tile "sel_edit" 2)
)

; SELECTION EDIT BOX에 입력된 SYMBOL 명이 실제로 존재하는가
; 를 확인한 후 존재하면 T, 존재하지 않으면 NIL을 리턴한다.

(defun check-symbol (type ln)
    (if (not (tblsearch type ln))
        (progn
            (do-error type)
            nil
        )
        T
    )
)

; SELECTION EDIT BOX에 입력이 발생했을 때 수행되는 CALL BACK 함수
; 입력된 SYMBOL 명이 실제로 존재하는가를 확인한다.

(defun do-select ( / sel)
    (setq sel (strcase (get_tile "sel_edit")))
    (if (check-symbol (car (nth #TABLETYPE #TABLELIST)) sel)
        (progn
            (setq #SYMBOLNAME sel)
            (set_tile "error" "")
            T
        )
        nil
    )
)

; OK BUTTON이 선택되었을 때 수행되는 CALL BACK 함수

(defun do-accept ()
    (if (do-select)
        (done_dialog)
    )
)

; CANCEL BUTTON이 선택되었을 때 수행되는 CALL BACK 함수

(defun do-cancel ()
    (done_dialog)
    (exit)
)

; Table Type Radio Button 처리를 위한 CALL BACK 함수

(defun do-table ( / ret pat)
    (setq ret (get_tile "type_but"))
    (cond ((= ret "block_but") (setq #TABLETYPE 0))
          ((= ret "dim_but")   (setq #TABLETYPE 1))
          ((= ret "layer_but") (setq #TABLETYPE 2))
          ((= ret "ltype_but") (setq #TABLETYPE 3))
          ((= ret "style_but") (setq #TABLETYPE 4))
          ((= ret "ucs_but")   (setq #TABLETYPE 5))
          ((= ret "view_but")  (setq #TABLETYPE 6))
          ((= ret "vport_but") (setq #TABLETYPE 7))
    )

    (setq pat "*")

    (set_tile "error" "")
    (set_tile "pat_edit" pat)
    (set_tile "table_title"
        (strcat (cadr (nth #TABLETYPE #TABLELIST)) "s Defined in this Drawing"))

    (mode_tile (caddr (nth #TABLETYPE #TABLELIST)) 2)

    (symbol-list "pat_list" (car (nth #TABLETYPE #TABLELIST)) pat)

    (setq erase-table (eval (cadddr (nth #TABLETYPE #TABLELIST))))
)

; SYMBOL 선택을 위한 DIALOGUE를 구성하고 CALL BACK 함수를 정의한다.

(defun symbol-dialog ( / dcl_id)
    (setq dcl_id (load_dialog "SYMBOL"))
    (if (not (new_dialog "table_box" dcl_id)) (exit))

    (do-table)

    (action_tile "type_but" "(do-table)")
    (action_tile "pat_edit" "(do-pattern)")
    (action_tile "pat_list" "(do-patlist)")
    (action_tile "sel_edit" "(do-select)")
    (action_tile "accept"   "(do-accept)")
    (action_tile "cancel"   "(do-cancel)")

    (start_dialog)
    (unload_dialog dcl_id)
)

; 테이블 형태에 따라 해당 엔티티를 삭제하는 함수

(defun erase-entity (type ln / ss)
    (cond
        ((= type "BLOCK")    (setq ss (list (cons 0 "INSERT") (cons 2 ln))))
        ((= type "DIMSTYLE") (setq ss (list (cons 0 "DIMENSION") (cons 3 ln))))
        ((= type "LAYER")    (setq ss (list (cons 8 ln))))
        ((= type "LTYPE")    (setq ss (list (cons 6 ln))))
        ((= type "STYLE")    (setq ss (list (cons 0 "TEXT") (cons 7 ln))))
    )
    (if (setq ss (ssget "X" ss))
        (command "ERASE" ss "")
        (princ (strcat "\nUnreferenced " type "."))
    )
    ; 이후에 PURGE 명령을 수행해야만 지정 테이블이 완전히 삭제됩니다.
)

; 테이블 형태에 따라 해당 테이블 정의를 삭제하는 함수

(defun erase-define (type ln)
    (cond ((= type "UCS")   (command "UCS"))
          ((= type "VIEW")  (command "VIEW"))
          ((= type "VPORT") (command "VPORTS"))
    )
    (command "DEL" ln)
)

; 전체 프로그램을 C:DELTABLE 함수로 정의한다.

(defun C:DELTABLE ()
    (setq #SYMBOLNAME "")
    (push-mode)
    (symbol-dialog)
    (erase-table (car (nth #TABLETYPE #TABLELIST)) #SYMBOLNAME)
    (redraw)
    (pop-mode)
)